// Test des signes randomisé en agronomie
// simulation des rendements des parcelles sous deux engrais A et A
// et réalisation du test de niveau exact alpha
// sous H0: pas d'amélioration rendement
n=10;
alpha=0.05;
// On suppose les rendements gaussiens de paramètres m et sigma
// choisis comme suit 
moy=10+3.*rand(1:n,'uniform');
sig=2+rand(1:n,'uniform');
Z=rand(2,n,'normal');
X=moy+sig.*Z(1,:);
Y=moy+sig.*Z(2,:);
// affichage des rendements
// avec colonne de signes '+' si X<Y, '-' sinon
//
// initialisation d'une colonne de '+'
plus='+';
col=plus(ones(n,1));
// modification par indexation booléenne
col(X'>=Y')='-';
//
printf('\n%6s%13s%13s%6s','Champ','Rendement A','Rendement B','Gain')
printf('%6d%13.2f%13.2f%6s\n',(1:n)',X',Y',col)
printf('\n%s%.2f',' Test des signes randomisé, au niveau alpha=',alpha)
//
// Calculs pour le test:
U=bool2s(X<Y);
S=sum(U);
salpha=invfdrbin(n,0.5,1-alpha);
b=loibin(n,0.5);   // ainsi b(1+salpha)=P(S=salpha) 
p=(alpha-1+fdrbin(n,0.5,salpha))./ b(1+salpha);
// Ces instructions supposent que l'on ait déjà chargé Binomiales.sci
// à adapter donc!
rejet="Rejet de l''hypothèse de non amélioration du rendement";
acceptation="Acceptation de l''hypothèse de non amélioration du rendement";
//
if S<salpha then
   disp(acceptation)
elseif S>salpha then
   disp(rejet)
else                                    // cas S=salpha
      if rand(1,1,'uniform')<p then     // rejet avec proba p
         disp(rejet)
      else                              // acceptation avec proba 1-p
         disp(acceptation)
      end
end