// Le peigne des intervalles de confiance pour 
// l'estimation d'une probabilité inconnue (niveau 95%)
// On affiche les deux types d'intervalles de confiance:
// avec variance majorée par 1/4 et avec varaince estimée
// Saisie des parametres 
n=input('Taille d''echantillon ?'); 
p=input('Rentrer la probabilité p à estimer:');
Mn=zeros(1:100); // initialisation des moyennes arithmétiques
a=zeros(1:100);b=zeros(1:100);
A=zeros(1:100);B=zeros(1:100);;
couleur=ones(2,100);
for i=1:100,
    X=bool2s(rand(1:n,"uniform")<p);Mn(i)=sum(X)./n;
    a(i)=Mn(i)-1.96.*(4.*n).^(-0.5);
    b(i)=Mn(i)+1.96.*(4.*n).^(-0.5);
    A(i)=Mn(i)-1.96.*sqrt(Mn(i).*(1-Mn(i))./n);
    B(i)=Mn(i)+1.96.*sqrt(Mn(i).*(1-Mn(i))./n);
    if (p<a(i))|(p>b(i)) then 
         couleur(1,i)=5; // rouge si p hors intervalle
    else couleur(1,i)=13; //  vert si p dans intervalle
    end,
    if (p<A(i))|(p>B(i)) then 
         couleur(2,i)=5; // rouge si p hors intervalle
    else couleur(2,i)=13; //  vert si p dans intervalle
    end,
end       
xbasc();
xsetech([0,0,1,0.5]);
plot2d([0 100],[0 1],[-1 -1],"021");// astuce pour fixer le cadre
titregauche="Intervalles de confiance au niveau 95%, variance majorée, ";
titredroit="100 échantillons de taille : "+string(n);
xtitle(titregauche + titredroit);
xsegs([0 100],[p p],[2]); // horizontale p
xsegs([1:100; 1:100],[a; b],couleur(1,:));
//
xsetech([0,0.5,1,0.5]);
plot2d([0 100],[0 1],[-1 -1],"021");
Titregauche="Intervalles de confiance au niveau 95%, variance estimée, ";
Titredroit="memes échantillons que ci-dessus";
xtitle(Titregauche + Titredroit);
xsegs([0 100],[p p],[2]);  
xsegs([1:100; 1:100],[A; B],couleur(2,:));