// Tests des signes déterministe et randomisé en agronomie
// simulation des rendements des parcelles sous deux engrais A et A
// et réalisation du test de niveau exact alpha
// sous H0: pas d'amélioration rendement
// on cherche la fréquence empirique de rejet à tort de H0
n=10;
alpha=0.05;
N=5000;
//
// On suppose les rendements gaussiens de paramètres m et sigma
// choisis comme suit 
moy=10+3.*rand(1:n,'uniform');
sig=2+rand(1:n,'uniform');
X=zeros(N,n);Y=zeros(N,n);
Z=rand(N,2*n,'normal');
for j=1:n, X(:,j)=moy(j)+sig(j).*Z(:,j); end
for j=1:n, Y(:,j)=moy(j)+sig(j).*Z(:,n+j); end
// Calculs pour le test:
U=bool2s(X<Y);
S=sum(U,'c');
salpha=invfdrbin(n,0.5,1-alpha);
b=loibin(n,0.5);   // ainsi b(1+salpha)=P(S=salpha) 
p=(alpha-1+fdrbin(n,0.5,salpha))./ b(1+salpha);
// Ces instructions supposent que l'on ait déjà chargé Binomiales.sci
// Test des signes déterministe
testdet=(S>salpha);  // vecteur booleen (N,1), T= rejet, F=acceptation
ftd=sum(bool2s(testdet))./N;  // fréquence erreurs 1ère espèce 
// Test des signes randomisé
V=rand(S,'uniform');
testrand=(S>salpha)|((S==salpha)&(V<p));  // attention == et pas =
ftr=sum(bool2s(testrand))./N;   //fréquence d'erreurs de 1ère espèce    

printf('\nAvec alpha=%.3f et sur %d simulations, on observe\n...
une  fréquence empirique d''erreurs du premier type de\n...
%6.3f pour le test déterministe\n...
%6.3f pour le test randomisé',alpha,N,ftd,ftr)